USB 드라이버

텍스트 파일를 아무거나 빈 창으로 만들고, 아래 내용을 복사해 넣습니다. 아무 이름으로든 저장합니다.

저장한 파일의 확장자를 bat로 바꿉니다. 이제 더블 클릭해서 실행합니다.

​

@prompt $s

@color 1f

@cd /d %tmp%

@title 윈10 중복드라이브 표기해결

@mode con cols=200 lines=50

@setlocal enabledelayedexpansion

​

@echo 관리자권한 확인용 >%windir%\admin.confirm || @(

echo Set UAC = CreateObject^("Shell.Application"^) > "%tmp%\admin.vbs"

echo UAC.ShellExecute "%~0", "", "", "runas", 1 >> "%tmp%\admin.vbs"

wscript.exe "%tmp%\admin.vbs" & del "%tmp%\admin.vbs" & exit)

@del %windir%\admin.confirm

​

@echo.

@echo.

@echo. === Windows 10 드라이브 중복 표기와 관련된 레지스트리 값을 제거 합니다. 원상복구도 지원합니다 ===

@echo.

@pause

​

reg query HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Desktop\NameSpace\DelegateFolders\{F5FB2C77-0E2F-4A16-A381-3E560C68BC83} || goto add

​

:: remove

​

if exist _.reg del /f/a/q _.reg

>>_.reg echo.Windows Registry Editor Version 5.00

>>_.reg echo.[-HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Desktop\NameSpace\DelegateFolders\{F5FB2C77-0E2F-4A16-A381-3E560C68BC83}]

​

if exist %windir%\SysWOW64 call :x64_remove

​

reg import _.reg

if exist _.reg del /f/a/q _.reg

​

@echo.

@echo. === 완료했습니다. 다시 실행하시면 원상복구됩니다 ===

@echo.

@pause

@exit

​

:add

​

if exist _.reg del /f/a/q _.reg

>>_.reg echo.Windows Registry Editor Version 5.00

>>_.reg echo.[HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Desktop\NameSpace\DelegateFolders\{F5FB2C77-0E2F-4A16-A381-3E560C68BC83}]

>>_.reg echo.@="Removable Drives"

​

if exist %windir%\SysWOW64 call :x64_add

​

reg import _.reg

if exist _.reg del /f/a/q _.reg

​

@echo.

@echo. === 원상복구했습니다. 다시 실행하시면 중복 제거됩니다 ===

@echo.

@echo. === 처음에 에러 표시는 레지스트리 확인하는데 레지스트리가 없어서 생기는 것이라서 문제 없는 겁니다 ===

@echo.

@pause

@exit

​

:x64_remove

​

>>_.reg echo.[-HKEY_LOCAL_MACHINE\SOFTWARE\WOW6432Node\Microsoft\Windows\CurrentVersion\Explorer\Desktop\NameSpace\DelegateFolders\{F5FB2C77-0E2F-4A16-A381-3E560C68BC83}]

exit/b

​

:x64_add

​

>>_.reg echo.[HKEY_LOCAL_MACHINE\SOFTWARE\WOW6432Node\Microsoft\Windows\CurrentVersion\Explorer\Desktop\NameSpace\DelegateFolders\{F5FB2C77-0E2F-4A16-A381-3E560C68BC83}]

>>_.reg echo.@="Removable Drives"

exit/b